1 /* -*-C-*-
2 * Lexical scanner for command line parsing
3 *
4 * Copyright 1993 Eric Youngdale
5 * 2000 Eric Pouech
6 *
7 * This library is free software; you can redistribute it and/or
8 * modify it under the terms of the GNU Lesser General Public
9 * License as published by the Free Software Foundation; either
10 * version 2.1 of the License, or (at your option) any later version.
11 *
12 * This library is distributed in the hope that it will be useful,
13 * but WITHOUT ANY WARRANTY; without even the implied warranty of
14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 * Lesser General Public License for more details.
16 *
17 * You should have received a copy of the GNU Lesser General Public
18 * License along with this library; if not, write to the Free Software
19 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
20 */
21
22 %option noinput nounput interactive 8bit prefix="dbg_"
23
24 %{
25 #include "config.h"
26 #include <stdlib.h>
27 #include <string.h>
28 #include <stdarg.h>
29
30 #define YY_NO_UNISTD_H
31 #include "debugger.h"
32 #include "dbg.tab.h"
33
34 #undef YY_INPUT
35
36 static char** local_lexemes /* = NULL */;
37 static int next_lexeme /* = 0 */;
38 static int alloc_lexeme /* = 0 */;
39
40 char* lexeme_alloc_size(int size)
41 {
42 assert(0 <= next_lexeme && next_lexeme < alloc_lexeme + 1);
43 if (next_lexeme >= alloc_lexeme)
44 {
45 alloc_lexeme += 32;
46 local_lexemes = dbg_heap_realloc(local_lexemes, alloc_lexeme * sizeof(local_lexemes[0]));
47 assert(local_lexemes);
48 }
49 return local_lexemes[next_lexeme++] = HeapAlloc(GetProcessHeap(), 0, size + 1);
50 }
51
52 static char* lexeme_alloc(const char* lexeme)
53 {
54 char* ptr = lexeme_alloc_size(strlen(lexeme) + 1);
55 return strcpy(ptr, lexeme);
56 }
57
58 void lexeme_flush(void)
59 {
60 while (--next_lexeme >= 0) HeapFree(GetProcessHeap(), 0, local_lexemes[next_lexeme]);
61 next_lexeme = 0;
62 }
63
64 static int read_input(const char* pfx, char* buf, int size)
65 {
66 int len;
67 static char* last_line = NULL;
68 static size_t last_line_idx = 0;
69
70 /* try first to fetch the remaining of an existing line */
71 if (last_line_idx == 0)
72 {
73 char* tmp = NULL;
74 /* no remaining chars to be read from last line, grab a brand new line up to '\n' */
75 lexeme_flush();
76 len = input_fetch_entire_line(pfx, &tmp);
77 if (len < 0) return 0; /* eof */
78
79 /* remove carriage return in newline */
80 if (len >= 2 && tmp[len - 2] == '\r')
81 {
82 tmp[len - 2] = '\n';
83 tmp[len - 1] = '\0';
84 len--;
85 }
86
87 /* FIXME: should have a pair of buffers, and switch between the two, instead of
88 * reallocating a new one for each line
89 */
90 if (last_line && (len == 0 || (len == 1 && tmp[0] == '\n')))
91 {
92 HeapFree(GetProcessHeap(), 0, tmp);
93 }
94 else
95 {
96 HeapFree(GetProcessHeap(), 0, last_line);
97 last_line = tmp;
98 }
99 }
100
101 len = min(strlen(last_line + last_line_idx), size - 1);
102 memcpy(buf, last_line + last_line_idx, len);
103 buf[len] = '\0';
104 if ((last_line_idx += len) >= strlen(last_line))
105 last_line_idx = 0;
106 return len;
107 }
108
109 #define YY_INPUT(buf,result,max_size) \
110 if ((result = read_input("Wine-dbg>", buf, max_size)) < 0) \
111 YY_FATAL_ERROR("read_input in flex scanner failed");
112
113 static int syntax_error;
114 %}
115
116 DIGIT [0-9]
117 HEXDIGIT [0-9a-fA-F]
118 FORMAT [ubcdgiswxa]
119 IDENTIFIER [_a-zA-Z~?][_a-zA-Z0-9~?@]*
120 PATHNAME [\\/_a-zA-Z0-9\.~@][\\/\-_a-zA-Z0-9\.~@]*
121 STRING \"[^\n"]+\"
122
123 %s FORMAT_EXPECTED
124 %s INFO_CMD
125 %s HELP_CMD
126 %s BD_CMD
127 %s LOCAL_CMD
128 %s SHOW_CMD
129 %s MODE_CMD
130 %s MAINT_CMD
131 %s NOCMD
132 %s PATH_ACCEPTED
133
134 %x PATH_EXPECTED
135 %x ASTRING_EXPECTED
136 %x NOPROCESS
137 %%
138 /* set to special state when no process is loaded. */
139 if (!dbg_num_processes() && YYSTATE == INITIAL) {BEGIN(NOPROCESS);}
140
141 <<EOF>> { return tEOF; }
142 <*>\n { BEGIN(INITIAL); syntax_error = 0; return tEOL; }
143 /* Indicates end of command. Reset state. */
144
145 "||" { return OP_LOR; }
146 "&&" { return OP_LAND; }
147 "==" { return OP_EQ; }
148 "!=" { return OP_NE; }
149 "<=" { return OP_LE; }
150 ">=" { return OP_GE; }
151 "<<" { return OP_SHL; }
152 ">>" { return OP_SHR; }
153 "->" { return OP_DRF; }
154 "::" { return OP_SCOPE; }
155 "[" { return *yytext; }
156 "]" { return *yytext; }
157
158 "0x"{HEXDIGIT}+ { sscanf(yytext, "%lx", &dbg_lval.integer); return tNUM; }
159 {DIGIT}+ { sscanf(yytext, "%ld", &dbg_lval.integer); return tNUM; }
160
161 <FORMAT_EXPECTED>"/"{DIGIT}+{FORMAT} { char* last;
162 dbg_lval.integer = strtol(yytext+1, &last, 0) << 8;
163 dbg_lval.integer |= *last;
164 return tFORMAT; }
165
166 <FORMAT_EXPECTED>"/"{FORMAT} { dbg_lval.integer = (1 << 8) | yytext[1]; return tFORMAT; }
167
168 {STRING} { dbg_lval.string = lexeme_alloc(yytext + 1); dbg_lval.string[strlen(dbg_lval.string) - 1] = '\0'; return tSTRING; }
169 <ASTRING_EXPECTED>[^\n]+ { char* p = yytext; while (*p == ' ' || *p == '\t') p++;
170 dbg_lval.string = lexeme_alloc(p); return tSTRING; }
171
172 <INITIAL,NOPROCESS>info|inf|in { BEGIN(INFO_CMD); return tINFO; }
173 <INITIAL>up { BEGIN(NOCMD); return tUP; }
174 <INITIAL>down|dow|do { BEGIN(NOCMD); return tDOWN; }
175 <INITIAL,INFO_CMD>frame|fram|fra|fr { BEGIN(NOCMD); return tFRAME; }
176 <INITIAL>list|lis|li|l { BEGIN(PATH_ACCEPTED); return tLIST; }
177 <INITIAL>enable|enabl|enab|ena { BEGIN(BD_CMD); return tENABLE;}
178 <INITIAL>disable|disabl|disab|disa|dis { BEGIN(BD_CMD); return tDISABLE; }
179 <INITIAL>disassemble|disassembl|disassemb|disassem|disasse|disass|disas { BEGIN(NOCMD); return tDISASSEMBLE; }
180 <INITIAL>locally|local { BEGIN(LOCAL_CMD); return tLOCAL; }
181 <INITIAL,LOCAL_CMD>display|displa|displ|disp { BEGIN(FORMAT_EXPECTED); return tDISPLAY; }
182 <INFO_CMD,BD_CMD>display|displa|displ|disp|dis|di|d { BEGIN(NOCMD); return tDISPLAY; }
183 <INITIAL>undisplay|undispla|undispl|undisp|undis|undi|und { BEGIN(NOCMD); return tUNDISPLAY; }
184 <INITIAL>delete|delet|dele|del { BEGIN(BD_CMD); return tDELETE; }
185 <INITIAL,NOPROCESS>quit|qui|qu|q { BEGIN(NOCMD); return tQUIT; }
186 <INITIAL>set|se { BEGIN(NOCMD); return tSET; }
187 <INITIAL>x { BEGIN(FORMAT_EXPECTED); return tEXAM; }
188 <INITIAL,NOPROCESS>help|hel|he|"?" { BEGIN(HELP_CMD); return tHELP; }
189
190 <INITIAL,NOPROCESS>backtrace|backtrac|backtra|backt|back|bac|ba|bt { BEGIN(NOCMD); return tBACKTRACE; }
191 <INITIAL,NOPROCESS>where|wher|whe { BEGIN(NOCMD); return tBACKTRACE; }
192
193 <INITIAL>cont|con|co|c { BEGIN(NOCMD); return tCONT; }
194 <INITIAL>pass|pas|pa { BEGIN(NOCMD); return tPASS; }
195 <INITIAL>condition|conditio|conditi|condit|condi|cond { BEGIN(NOCMD); return tCOND; }
196 <INITIAL>step|ste|st|s { BEGIN(NOCMD); return tSTEP; }
197 <INITIAL>next|nex|ne|n { BEGIN(NOCMD); return tNEXT; }
198 <INITIAL>stepi|si { BEGIN(NOCMD); return tSTEPI; }
199 <INITIAL>nexti|ni { BEGIN(NOCMD); return tNEXTI; }
200 <INITIAL>finish|finis|fini|fin|fi { BEGIN(NOCMD); return tFINISH; }
201
202 <INITIAL>abort|abor|abo { BEGIN(NOCMD); return tABORT; }
203 <INITIAL>print|prin|pri|pr|p { BEGIN(FORMAT_EXPECTED); return tPRINT; }
204
205 <INITIAL>show|sho|sh { BEGIN(SHOW_CMD); return tSHOW; }
206 <INITIAL,NOPROCESS>source|sourc|sour|src { BEGIN(PATH_EXPECTED); return tSOURCE; }
207 <INITIAL>symbolfile|symbols|symbol|sf { BEGIN(PATH_EXPECTED); return tSYMBOLFILE; }
208
209 <INITIAL,INFO_CMD,BD_CMD>break|brea|bre|br|b { BEGIN(PATH_ACCEPTED); return tBREAK; }
210 <INITIAL,INFO_CMD,BD_CMD>hbreak|hbrea|hbre|hbr|hb { BEGIN(PATH_ACCEPTED); return tHBREAK; }
211 <INITIAL>watch|watc|wat { BEGIN(NOCMD); return tWATCH; }
212 <INITIAL>rwatch|rwatc|rwat { BEGIN(NOCMD); return tRWATCH; }
213 <INITIAL>whatis|whati|what { BEGIN(NOCMD); return tWHATIS; }
214 <INITIAL,NOPROCESS>run|ru|r { BEGIN(ASTRING_EXPECTED); return tRUN;}
215 <INITIAL>detach|detac|deta|det { BEGIN(NOCMD); return tDETACH; }
216 <INITIAL>kill|kil|ki|k { BEGIN(NOCMD); return tKILL; }
217 <INITIAL,NOPROCESS>maintenance|maint { BEGIN(MAINT_CMD); return tMAINTENANCE; }
218 <INITIAL>minidump|mdmp { BEGIN(PATH_EXPECTED); return tMINIDUMP; }
219 <INITIAL>echo { BEGIN(ASTRING_EXPECTED); return tECHO; }
220 <NOPROCESS>attach|attac|atta|att { BEGIN(NOCMD); return tATTACH; }
221 <INFO_CMD>share|shar|sha { return tSHARE; }
222 <MAINT_CMD>module|modul|mod { BEGIN(ASTRING_EXPECTED); return tMODULE; }
223 <INFO_CMD>locals|local|loca|loc { return tLOCAL; }
224 <INFO_CMD>class|clas|cla { return tCLASS; }
225 <INFO_CMD>process|proces|proce|proc { return tPROCESS; }
226 <INFO_CMD>threads|thread|threa|thre|thr|th { return tTHREAD; }
227 <INFO_CMD>exception|except|exc|ex { return tEXCEPTION; }
228 <INFO_CMD>registers|regs|reg|re { return tREGS; }
229 <INFO_CMD>allregs|allreg|allre { return tALLREGS; }
230 <INFO_CMD>"all-registers"|"all-regs"|"all-reg"|"all-re" { return tALLREGS; }
231 <INFO_CMD>segments|segment|segm|seg|se { return tSEGMENTS; }
232 <INFO_CMD>stack|stac|sta|st { return tSTACK; }
233 <INFO_CMD>symbol|symbo|symb|sym { BEGIN(ASTRING_EXPECTED); return tSYMBOL; }
234 <INFO_CMD>maps|map { return tMAPS; }
235 <INFO_CMD>window|windo|wind|win|wnd { return tWND; }
236 <HELP_CMD>info|inf|in { return tINFO; }
237 <MAINT_CMD>type { return tTYPE; }
238
239 <INITIAL,SHOW_CMD>directories|directorie|directori|director|directo|direct|direc|direc|dir {
240 BEGIN(PATH_EXPECTED); return tDIR; }
241
242 char { return tCHAR; }
243 short { return tSHORT; }
244 int { return tINT; }
245 long { return tLONG; }
246 float { return tFLOAT; }
247 double { return tDOUBLE; }
248 unsigned { return tUNSIGNED; }
249 signed { return tSIGNED; }
250 struct { return tSTRUCT; }
251 union { return tUNION; }
252 enum { return tENUM; }
253 all { return tALL; }
254
255 {IDENTIFIER} { dbg_lval.string = lexeme_alloc(yytext); return tIDENTIFIER; }
256 "$"{IDENTIFIER} { dbg_lval.string = lexeme_alloc(yytext+1); return tINTVAR; }
257
258 <PATH_EXPECTED,PATH_ACCEPTED>{PATHNAME} { dbg_lval.string = lexeme_alloc(yytext); return tPATH; }
259
260 [-+<=>|&^()*/%:!~,\.] { return *yytext; }
261
262 <*>[ \t\r]+ /* Eat up whitespace and DOS LF */
263
264 <NOPROCESS>. { BEGIN(ASTRING_EXPECTED); yyless(0); return tNOPROCESS;}
265 <*>. { if (syntax_error == 0) { syntax_error++; dbg_printf("Syntax Error (%s)\n", yytext); } }
266 %%
267
268 #ifndef dbg_wrap
269 int dbg_wrap(void) { return 1; }
270 #endif
This page was automatically generated by the
LXR engine.
Visit the LXR main site for more
information.